# Copyright ©2005 Hugo Mills <hugo@carfax.org.uk>
#
# This software is distributed under the terms of the GNU GPL v2
# For more information on the GPL, see the file COPYING or 
# visit http://www.gnu.org/
#
# This software is distributed without warranty

dnl Process this file with autoconf to produce a configure script.
AC_INIT(organ/organ.cc)
AC_CANONICAL_SYSTEM
AC_CONFIG_HEADERS([config.h])

PACKAGE=organ
VERSION=0.0.0
AC_SUBST(PACKAGE)
AC_SUBST(VERSION)

dnl Checks for programs.
#AC_PREREQ
AC_PROG_AWK
AC_PROG_CC
AC_PROG_CXX
AC_PROG_INSTALL
AC_PROG_LN_S

AC_LANG_CPLUSPLUS
AC_C_INLINE

AC_LANG([C++])

# Tools for building a distribution tarball
AC_CHECK_PROG(TAR, [tar], "tar", "")
if test -z $TAR
then
        AC_MSG_ERROR([tar is not installed])
fi
AC_CHECK_PROGS(COMPRESS, [gzip bzip2 compress], "")
if test -z $COMPRESS 
then
        AC_MSG_ERROR([No compression tool found])
else
        case $COMPRESS in
                gzip)
                        COMPRESS_EXT=".gz" ;;
                bzip2)
                        COMPRESS_EXT=".bz2" ;;
                compress)
                        COMPRESS_EXT=".Z" ;;
        esac
fi
AC_SUBST(COMPRESS_EXT)

dnl Checks for libraries.
dnl Should check for whether this move is sensible (or needed)
CXXFLAGS="${CXXFLAGS} -D_GNU_SOURCE -D_REENTRANT"
OST_CCXX2_VERSION(1.0.13)

CGICC_CHECK_INSTALLATION()

dnl Check for libxml, libxml++, libxslt
PKG_CHECK_MODULES([LIBXML], libxml-2.0 >= 2.6 libxslt >= 1.1 libexslt >= 0.8.10 libxml++-2.6 >= 2.6)
AC_SUBST(LIBXML_CFLAGS)
AC_SUBST(LIBXML_LIBS)

PKG_CHECK_MODULES([SQLITE], sqlite3)
AC_SUBST(SQLITE_CFLAGS)
AC_SUBST(SQLITE_LIBS)

dnl Check for pion-net libs
PKG_CHECK_MODULES([PIONNET], pion-net >= 1.1.4)
AC_SUBST(PIONNET_CFLAGS)
AC_SUBST(PIONNET_LIBS)

dnl Checks for header files.
AC_HEADER_STDC
AC_HEADER_STDBOOL

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST

dnl Build options
cgibin=${exec_prefix}/cgi-bin
AC_ARG_WITH(
	[cgi-bin],
	[AS_HELP_STRING(
		[--with-cgi-bin=DIR],
		[path to install CGI scripts (EPREFIX/cgi-bin)]
		)],
	[cgibin=$with_cgi_bin]
	)
AC_SUBST(cgibin)

webdir=/var/www
AC_ARG_WITH(
	[webdir],
	[AS_HELP_STRING(
		[--with-webdir=DIR],
		[path to install static web content (/var/www)]
		)],
	[webdir=$with_webdir]
	)
AC_SUBST(webdir)

dnl Checks for library functions.
AC_OUTPUT(stamp-h \
	Makefile \
	organ/Makefile.mk \
	panpipe/Makefile.mk \
	)